trend主背景Init代码

int linesize = 0;  // linesize用于使刷新的时候不会生成多余的行

main()
{
  startThread("initTrend");
  delay(0.5);  // delay 0.5s 为了让Trend初始化
  startThread("showAlert");  // 创建一个线程，用于每隔5秒取一次报警信息
}

void initTrend()
{
  // 将数据读入dyn_string中
  
  // 打开文件
  file fileHandle = fopen("D://test1.txt", "r+");

  string line = "";
  dyn_string lines;
  while(!feof(fileHandle))  // 没有读取到最后一行
  {
    fgets(line, 100, fileHandle);  // 每一行读取100个字符，多读一点数据
    dyn_string str = strsplit(line, "\n");  // 去掉回车符
    if(dynlen(str) > 0) line = str[1];
    int len = strlen(line);
    while(len > 0 && line[len - 1] == " ") len -- ;  // 去掉后缀空格
    line = substr(line, 0, len);
    lines.append(line);
  }
  fclose(fileHandle);


  // 对dyn_string中的数据进行处理
  string trendName;
  int trendCount;
  for(int i = 1; i <= dynlen(lines); i ++ )
  {
    if(lines[i] == "")
    {
      // 没有内容不做处理
    }
    else if(strpos(lines[i], "trendName", 0) > 0)  // 记录trend名字
    {
      i ++ ;
      trendName = lines[i];
    }
    else if(strpos(lines[i], "curveCount", 0) > 0)  // 记录有多少条曲线
    {
      i ++ ;
      trendCount = (int)lines[i];
      for(int j = 1; j <= trendCount; j ++ )  // 初始化曲线
      {
        if(j != 1) setValue(trendName, "curveScaleVisibility", "curve" + j, false);
        if(j < trendCount) setValue(trendName, "linkCurves", "curve" + j, "curve" + (j + 1));
      }
    }
    else if(strpos(lines[i], "dp", 0) > 0)  // 添加dp
    {
      i ++ ;
      for(int j = 1; j <= trendCount; j ++ )
      {
        setValue(trendName, "connectDirectly", "curve" + j, lines[i ++ ]);
      }
      i -- ;
    }
    else if(strpos(lines[i], "curveName", 0) > 0)
    {
      i ++ ;
      for(int j = 1; j <= trendCount; j ++ )
      {
        setValue(trendName, "curveLegendName", "curve" + j, lines[i ++ ]);
      }
      i -- ;
    }
    else if(strpos(lines[i], "end", 0) > 0)
    {
       setValue(trendName, "legendFont", "Arial Black, -1, 14, 0, 0, 0, 0, 0, 0, 0");
       setValue(trendName, "trendRun");
    }
  }
}


string alertLevel(string key)  // 将报警等级转化为对应的报警说明
{
  string tmpkey;
  switch(key)
  {
    case "-2": tmpkey = "断网";break;
    case "-1": tmpkey = "停机";break;
    case "0": tmpkey = "正常";break;
    case "1": tmpkey = "智能一级";break;
    case "2": tmpkey = "智能二级";break;
    case "3": tmpkey = "智能三级";break;
    case "4": tmpkey = "固定高报";break;
    case "5": tmpkey = "固定高高报";break;
  }
  return tmpkey;
}

void showAlert()
{
  string url = "http://10.217.3.118:18000/wepp_compressor_query_alert";  // 报警查询地址

  mapping data = makeMapping(
          "equipmentUuid", "1c43870a56802127f80a2829feb3294c",
           "pageNumber", 1,
           "size", 20
      );  // 请求数据

  mapping result;  // 返回的数据

  while(true)
  {
    // 使用Post请求，读取数据，存入result中
    netPost(url,
        makeMapping(
        "content", jsonEncode(data, false),
        "headers", makeMapping("Content-Type", "application/json; charset=utf-8")
        ),
        result
      );

    // 验证传输数据是否有异常
    if(mappingHasKey(result, "content"))
      if(mappingHasKey(result, "httpStatusText") && result["httpStatusText"] == "OK")
        if(mappingHasKey(result, "httpStatusCode") && result["httpStatusCode"] == 200)
        {
          mapping mData = jsonDecode(result["content"]);
          dyn_mapping dmData = mData["data"]["content"];

          /*
            可以debugtn看看dmData是什么样的
            DebugTN(dmData);
          */

          // 从dmData中取报警数据
          for(int i = 1; i <= dynlen(dmData); i ++ )
          {
            mapping mItem = dmData[i];
            /*
              这里的mItem里面的数据大概为：
              key                 value
              alarmLevel            5
              alarmStartTime  32142145325231
              alarmEndTime    32582165325231
              pointName        高速轴驱温度
              ...             ...
            */

            if(linesize < 20) Table.appendLine("ID", i);
            linesize ++ ;

            // 开始绘制数据
            for(int k = 1; k <= mappinglen(mItem); k ++ )
            {
              string key = mappingGetKey(mItem, k);

              // 将不需要的信息舍去
              if(key != "alarmLevel" && key != "alarmEndTime"
                   && key != "alarmStartTime" && key != "pointName") continue;

              // 如果是
              // 1. 时间     按照时间的显示格式
              // 2. 报警等级  按照报警等级描述显示
              // 3. 其他     正常显示
              if(key == "alarmEndTime" || key == "alarmStartTime")
              {
                Table.cellValueRC(i - 1, key, formatTime("%y-%m-%d %H:%M:%S", (time)(mItem[key] / 1000)));
              }
              else if(key == "alarmLevel")
              {
                string tmpkey = alertLevel(mItem[key]);
                Table.cellValueRC(i - 1, key, tmpkey);
              }
              else
              {
                Table.cellValueRC(i - 1, key, mItem[key]);
              }
            }
          }
        }

    if(linesize > 10000) linesize = 30;

    delay(5);  // 每5秒查询一次
  }
}